Imports System.Reflection

Imports System.Text

Imports System.Security.Cryptography

' Sign the assembly with a Strong Name Key created with the .net Framework SDK 

' Strong Name Tool (Sn.exe).  This is important - it ensures that your assembly identity

' is sufficiently strong; so that it will not confict with other assemblies.

' 

' Sn.exe -k DotNetCryptoCOM.snk

'

' During Compilation and Build, VS.net will look for the strong name key in the same

' location as your solution (.sln) file.  You may have to move the .snk file there before build.

'

' Note: If you see the 'Error creating assembly manifest' during compilation, 

'       you may have copied in the .snk file while the solution was open. You should

'       try closing and re-opening the solution before the DLL will build successfully.

<Assembly: AssemblyKeyFileAttribute("DotNetCryptoCOM.snk")> 

' Note: You will also need to ensure that the project is not set to register for 

'       COM interop at this point.  To check, go to Project Properties, 

'       Config Properties, Build, and make sure that the "Register for COM Interop" 

'       is UNCHECKED.

'       We will manually register the signed assembly for COM interop using the RegAsm tool

'       after the DLL has been built.

Public Class CryptoClass

    ' m_CryptoServiceProvider Defines a wrapper object to access the cryptographic service provider

    ' This example uses the Data Encryption Standard (DES) symmetric cryptographic algorithm

    '

    ' Implementators that require use of other symmetric CryptoServiceProviders, 

    ' simply need to replace the DESCryptServiceProvider with one of the following

    ' .Net Symmetric Cryptographic Algorithm Implementations:

    '  DESCryptoServiceProvider

    '  RijndaelManaged 

    '  RC2CryptoServiceProvider

    '  TripleDESCryptoServiceProvider

    Private m_CryptoServiceProvider As DESCryptoServiceProvider

    ' Create the new CryptoServiceProvider

    Public Sub New()

        ' Replace the DESCryptoServiceProvider with another
	' symmetric algoritm implementation if desired

        m_CryptoServiceProvider = New DESCryptoServiceProvider

    End Sub

    ' Destroy the CryptoServiceProvider

    Protected Overrides Sub Finalize()

        m_CryptoServiceProvider = Nothing

        MyBase.Finalize()

    End Sub

    Public Function Encrypt(ByVal Source As String, ByVal Key As String) As String

        Dim bytIn As Byte() = System.Text.Encoding.ASCII.GetBytes(Source)

        ' Create a MemoryStream

        Dim ms As System.IO.MemoryStream = New System.IO.MemoryStream

        ' Ensure that the key is of legal size for the crypto algorithm

        Dim bytKey As Byte() = GetLegalKey(Key)

        ' Set the private key

        m_CryptoServiceProvider.Key = bytKey

        m_CryptoServiceProvider.IV = bytKey

        ' Create an Encryptor from the Provider Service instance

        Dim encrypto As ICryptoTransform = m_CryptoServiceProvider.CreateEncryptor()

        ' Create Crypto Stream that transforms a stream using the encryption

        Dim cs As CryptoStream = New CryptoStream(ms, encrypto, CryptoStreamMode.Write)

        ' Write out encrypted content into MemoryStream

        cs.Write(bytIn, 0, bytIn.Length)

        cs.Close()

        ' Convert into Base64

        Dim encrypted As Byte()

        encrypted = ms.ToArray

        Return System.Convert.ToBase64String(encrypted, 0, encrypted.Length)

    End Function

    Public Function Decrypt(ByVal Source As String, ByVal Key As String) As String

        ' Convert from Base64 to binary

        Dim bytIn As Byte() = System.Convert.FromBase64String(Source)

        ' Create a MemoryStream with the input

        Dim ms As System.IO.MemoryStream = New System.IO.MemoryStream(bytIn, 0, bytIn.Length)

        Dim bytKey As Byte() = GetLegalKey(Key)

        ' Set the private key

        m_CryptoServiceProvider.Key = bytKey

        m_CryptoServiceProvider.IV = bytKey

        ' Create a Decryptor from the Provider Service instance

        Dim encrypto As ICryptoTransform = m_CryptoServiceProvider.CreateDecryptor()

        ' Create Crypto Stream that transforms a stream using the decryption

        Dim cs As CryptoStream = New CryptoStream(ms, encrypto, CryptoStreamMode.Read)

        ' Read out the result from the Crypto Stream

        Dim sr As System.IO.StreamReader = New System.IO.StreamReader(cs)

        Return sr.ReadToEnd()

    End Function

    ' Depending on the legal key size limitations of a specific CryptoService provider

    ' and length of the private key provided, padding the secret key with space character

    ' to meet the legal size of the algorithm.

    Private Function GetLegalKey(ByVal Key As String) As Byte()

        Dim sTemp As String

        If (m_CryptoServiceProvider.LegalKeySizes.Length > 0) Then

            Dim minSize As Integer = m_CryptoServiceProvider.LegalKeySizes(0).MinSize

            Dim maxsize As Integer = m_CryptoServiceProvider.LegalKeySizes(0).MaxSize

            ' Key sizes are in bits

            If ((Key.Length * 8) > maxsize) Then

                ' Trim key to max-key size

                sTemp = Key.Substring(0, (maxsize / 8))

            Else

                If ((Key.Length * 8) < minSize) Then

                    ' Pad small key to minsize length with space

                    sTemp = Key.PadRight((minSize / 8), " ")

                Else

                    Dim lesssize As Integer = 0

                    Dim moresize As Integer = minSize

                    ' Get nearest Skipsize increment between minsize and maxsize that

                    ' corresponds with key length

                    Do While ((Key.Length * 8) > moresize)

                        lesssize = moresize

                        moresize += m_CryptoServiceProvider.LegalKeySizes(0).SkipSize

                    Loop

                    ' Pad mid-range key if necessary

                    sTemp = Key.PadRight((moresize / 8), " ")

                End If

            End If

        Else

                sTemp = Key

        End If

        ' Convert the secret key to byte array

        Return ASCIIEncoding.ASCII.GetBytes(sTemp)

    End Function

End Class

' Create a new CryptoServiceProvider

Set oCryptoProvider = CreateObject("DotNetCryptoCOM.CryptoClass")

' Note: That the default CryptoServiceProvider for this class (in this case DES)

' has a key-size of exactly 64 bits. Other symmetric algorithm implementations

' require keys of different sizes, and increments. 

' The CryptoClass caters for all of these different key sizes through the

' LegalKeySizes symmetric algorithm property. Keys provided to the class are checked

' against the known minimum, maximum and skip key sizes for each algorithm. 

' Long keys will be clipped, short keys will be padded with spaces.

' Data to encrypt:

strRawData = "All your base are belong to us"

' Encrypt the data with key "SECRETKEY"

strEncryptedData = oCryptoProvider.Encrypt(strRawData,"SECRETKEY")

' Decrypt the encrypted data with the same key

strDecryptedData = oCryptoProvider.Decrypt(strEncryptedData,"SECRETKEY")

' Write the a custom message to Custom01 (Fields.VarCustom01)

Fields.VarCustom01 = "Encrypted Data: " & strEncryptedData & vbCrLf & "Decrypted Data: " & _
                                strDecryptedData

' Destroy the CryptoServiceProvider

Set oCryptoProvider = Nothing

' Create a new CryptoServiceProvider

Set oCryptoProvider = CreateObject("DotNetCryptoCOM.CryptoClass")

' Note: That the default CryptoServiceProvider for this class (in this case DES)

' has a key-size of exactly 64 bits. Other symmetric algorithm implementations

' require keys of different sizes, and increments. 

' The CryptoClass caters for all of these different key sizes through the

' LegalKeySizes symmetric algorithm property. Keys provided to the class are checked

' against the known minimum, maximum and skip key sizes for each algorithm. 

' Long keys will be clipped, short keys will be padded with spaces.

' Data to encrypt:

strRawData = "All your base are belong to us"

' Encrypt the data with key "SECRETKEY"

strEncryptedData = oCryptoProvider.Encrypt(strRawData,"SECRETKEY")

' Decrypt the encrypted data with the same key

strDecryptedData = oCryptoProvider.Decrypt(strEncryptedData,"SECRETKEY")

' Message Popup

MsgBox "Encrypted Data: " & strEncryptedData & vbCrLf & "Decrypted Data: " & strDecryptedData

' Destroy the CryptoServiceProvider

Set oCryptoProvider = Nothing